Excel-Haushaltsbuch selbst erstellen

Ein selbst erstelltes Excel-Haushaltsbuch ist einer der ersten Schritte auf dem Weg in die finanzielle Freiheit. Aber auch dann, wenn die persönlichen Ziele anders aussehen, ist die Erstellung einer solchen Vorlage Investition in die eigene Person. Nur wer weiß, was am Ende jeden Monats unterm Strich übrigbleibt, kann dieses Geld sinnvoll und bestenfalls nachhaltig anlegen.

Ich zeige dir hier in einer Anleitung Schritt für Schritt, wie du dir ein Excel-Haushaltsbuch selbst erstellen kannst. Du erfährst, wie du deine Einnahmen, Ausgaben und sogar Sparraten digital protokollierst. Außerdem erkläre ich, wie du die Daten übersichtlich auswertest und analysierst (Tabellen + Diagramme). Zur besseren Verständlichkeit findest du sowohl anschauliche Bilder als auch alle relevanten Formeln. Soweit möglich, versuche ich die Funktion der Formeln zu erklären. Das heißt aber nicht, dass du unbedingt alles verstehen musst. Du darfst sie auch gerne direkt eins zu eins übernehmen.

Wichtige Infos zuerst

Was kann das Excel-Haushaltsbuch?

• Funktioniert ganz ohne Makros
• Übersichtlich – Separate Tabellenblätter für die Eingabe der Buchungen und die Auswertungen
• Alle privaten Einnahmen + Ausgaben + Sparraten können 1 Jahr (volles Kalenderjahr) protokolliert werden – also: ein Excel-Dokument für 2020, eines für 2021, usw.
• Unterteilung in variable und fixe Ausgaben
• Sparplan mit monatlichen Raten für Konsum- und Alterssparen
• Finanzen lassen sich in eigene, sinnvolle Haushaltsbuch-Kategorien einteilen
• Eingaben sind auf das Wesentliche begrenzt (Datum, Kategorie, Betrag und ggf. Bemerkung)
• Monats- und Jahresbilanz – Auswertung mit übersichtlichen Tabellen (nach Monat, Jahr und Kategorie)
• Grafische Auswertung in Form von Diagrammen (Gesamteinnahmen, Gesamtausgaben und Saldo sowie ein kumulierter Sparplan)
• Das Aussehen ist individuell gestaltbar und die Funktionen können nach Belieben geändert oder erweitert werden
• Das Excel-Dokument kann auf unterschiedlichen Endgeräten genutzt werden – Tipp: Wenn du es in der Cloud speicherst, kannst du deine Daten auch von unterwegs eingeben und auswerten (Internetempfang vorausgesetzt)

Falls du jetzt noch nicht zu 100% überzeugt bist, dann lies doch mal meinen Artikel zum Thema Haushaltsbuch führen. Dort findest du alles Wissenswerte über die Dokumentation der privaten Finanzen. Ab Kapitel 4 zeige ich dir meine wichtigsten Erkenntnisse mit meinem persönlichen Excel-Haushaltsbuch. Ich habe ca. 2018 damit angefangen und bin bis heute dabeigeblieben.

Was kann es (noch) nicht?

• Endlose Protokollierung der Finanzen in einem Dokument und damit ein direkter Vergleich zu den Vorjahren
• Budgetplanung für einzelne Ausgabenarten
• Belegerfassung und -verknüpfung mit den Buchungen
• Auswertung nach bestimmten Kategorien (Kreisdiagramm bzw. Tortendiagramm)
• Finanzieller Blick in die Zukunft – Kontoentwicklung auf Basis von Fixkosten und erkannter Konsumgewohnheiten
• Keine Kontoanbindung (Synchronisierung mit dem Girokonto)

Warum sollte ich ein Excel-Haushaltsbuch selbst erstellen?

Im Netzt gibt es viele kostenlose Excel-Haushaltsbuch-Vorlagen. Auch ich hab damals nach einer passenden gesucht. Jedoch vergebens. Denn die meisten der angebotenen Dokumente sind einerseits nicht nur lieblos erstellt, sondern andererseits leider auch oft wenig durchdacht. Eine Vorlage zu finden, die ich ohne aufwändigere Anpassungen direkt verwenden hätte können, war für meine Anforderungen nicht möglich.

Eines, was ich immer ändern wollte, waren die Einnahme- und Ausgabearten, also die Kategorien. Aber selbst hierfür muss man verstehen, wie die Tabellen und Formeln aufgebaut sind. Das ist nicht immer ganz ersichtlich und meist sehr zeitaufwändig. Ein anderer Bereich war die Auswertung. Die vorhandenen Tabellen und Diagramme haben mir nicht ausgereicht. Deshalb musste ich fast immer eine eigene Lösung erarbeiten. Vielleicht geht es dir ja ähnlich, aber meiner Meinung nach gibt es zu viele Nachteile fertiger Haushaltsbuch-Vorlagen, die mich dazu veranlasst haben, eine eigene zu erstellen.

Du möchtest aber nicht wissen, was andere schlechter machen. Sondern, was du besser machen kannst. Deshalb hier drei Vorteile, die dafür sprechen, eine Excel-Haushaltsbuch-Vorlage selbst zu erstellen:

• Erster wichtiger Überblick über die eigenen Einnahmen und Ausgaben:
  Bei der Erstellung eines Haushaltsbuchs musst du dich zwangsläufig im Voraus mit deinen Finanzen auseinandersetzen. Nicht zu unterschätzen ist dabei die Erstellung der Liste mit den Haushaltsbuch-Kategorien. Nimm dir die Zeit. Denn in dieser Phase stellt sich meist schon einer erster Aha-Effekt ein. Außerdem ist eine individuell abgestimmte Liste die Grundlage für die spätere Auswertungen deiner Daten. Nur durch eine sinnvolle Kategorisierung kannst du bspw. Sparpotenziale sowie (schlechte) Konsumgewohnheiten entdecken und letztendlich die richtigen Schlüsse ziehen.
• Individuelle Möglichkeiten zur Gestaltung und Auswertung:
  Eine eigene Excel-Haushaltbuch-Vorlage ist flexibel. Unnütze Dinge, wie sie oft in kostenlosen Downloads enthalten sind, kannst du pauschal von Anfang an weglassen. Du kannst dich auf das Wesentliche und auf das für dich Relevante konzentrieren. Und das wichtigste, alle Tabellen und Diagramme lassen sich personalisieren (Inhalte + Design).
• Excel-Kenntnisse auffrischen und vertiefen:
  Eine einfache Addition, Subtraktion oder ein Produkt bekommen die meisten hin. Die Ermittlung des Mittelwerts oder der Anzahl von Werten in einer Zeile oder Spalte ist auch noch geläufig. Aber dann hört es oft schon auf.
  Ein weiterer guter Grund, weshalb es Sinn macht, ein eigenes Haushaltsbuch zu programmieren – du wirst deine Excel-Kenntnisse ausbauen. Und falls du mal nicht weiterkommst, frag die Suchmaschine deines Vertrauens. Für fast jedes Problem gibt es im Netz eine Lösung. Außerdem gilt auch in Excel das Sprichwort „Viele Wege führen nach Rom“. Meine hier vorgestellte Anleitung soll nur eine Orientierung darstellen. Ich hab‘ nichts dagegen, wenn du für einige Funktionen einen viel effizienteren Weg findest. Im Gegenteil, ich würde mich freuen – und du dich bestimmt auch.

Schritt für Schritt zur eigenen Excel-Haushaltsbuch-Vorlage

Hinweis: Um die Bilder aussagekräftiger zu machen, habe ich die Tabellen mit Werten gefüllt. Ich empfehle dir ebenfalls, ein paar Einnahmen, Ausgaben und Sparraten einzutragen (z. B. welche für die Monate Januar, Februar, Juli und Dezember). So kannst du einerseits direkt überprüfen, ob deine Formeln funktionieren. Außerdem sind die Formatierungen unmittelbar sichtbar – vor allem die bedingte Formatierung einiger Zellen.

1. Vorbereitungen

Intelligente Tabellen nutzen

Bevor es ins Eingemachte geht, möchte ich auf ein sinnvolles Feature von Excel aufmerksam machen, welches noch viel zu selten wirklich genutzt wird: intelligente Tabellen.

Jede Tabelle, die ich erstelle, versehe ich sozusagen mit einer Intelligenz, auf die ich hier aber nicht weiter eingehen möchte. Nur so viel: es erleichtert geplante Auswertungen und macht aufwändigere Formeln übersichtlicher und weniger fehleranfällig. Nutzen kann man die Funktionalität, wenn die jeweiligen Tabellen über die Menü-Schaltfläche Als Tabelle formatieren formatiert werden. Oder noch schneller, mit dem Shortcut STRG + T in Windows bzw. cmd + T in MacOS.

Wird nichts manipuliert, so benennt Excel die intelligenten Tabellen von Tabelle1 bis TabelleX. Um das Ganze jedochein wenig übersichtlicher zu halten, benenne ich die Tabellen in folgendem Schema:

• Tabellen zur Auswertung und Erfassung der Daten = tab_Tabellenname
• Hilfstabellen = hilfstab_Tabellenname

Der Menüpunkt Tabelle (MacOS) bzw. Tabellenentwurf (Windows) gibt die Möglichkeit, die einzelnen Tabellen mit unterschiedlichen Tabellenvorlagen zu formatieren. Dies nutze ich natürlich, so z.B. für die Ausgaben (orange), Einnahmen (grün) und den Sparplan (blau).

Interessant sind auch die Checkboxen. Diese haben einerseits Auswirkungen auf das Aussehen der Tabelle, aber viel wichtiger sind die zusätzlichen Funktionen. Das meiste ist selbsterklärend. Einfach mal austesten.

Hilfstabellen erstellen

Meine Einnahmen, Ausgaben und Sparraten möchte ich in sinnvolle Haushaltsbuch-Kategorien verbuchen. Die Kategorisierung aber jedes Mal als Text einzugeben, wäre sehr umständlich und fehleranfällig. Eine bessere Lösung ist der Weg über die Auswahlliste. So muss ich die Daten nur einmal eingeben und kann sie anschließend an der entsprechenden Stelle ganz einfach per Klick auswählen und einfügen.

Für solche sich wiederholende Eingabedaten erstelle ich ein separates Tabellenblatt mit dem Namen Hilfstabellen. Das dient der Übersichtlichkeit und Struktur.

Hierin liste ich nun alle notwendigen Tabellen in Form intelligenter Tabellen auf:

• Ausgabenart = hilfstab_Ausgaben_fix, hilfstab_Ausgaben_variabel
• Einnahmenart = hilfstab_Einnahmen
• Sparart = hilfstab_Sparen

Falls notwendig, können diese dann ohne Weiteres bearbeitet und/ oder erweitert werden.

2. Ausgaben erfassen

Bei den meisten kostenlos angebotenen Excel-Haushaltsbüchern müssen die Ausgaben direkt in die Übersichtstabelle eingegeben werden. Dabei habe ich zwar die Möglichkeit, sie in die jeweilige Ausgabenart bzw. -kategorie einzutragen, aber es ist oft nur eine Zelle dafür vorgesehen. Doch was ist, wenn es mal mehrere Kosten derselben Kategorie gibt? In dem Fall könnte man die einzelnen Posten (z.B. in Form von Kassenzetteln) sammeln und um Ende des Monats als Gesamtsumme eintragen. Oder man trägt in der betroffenen Zelle eine Summe aus den einzelnen Posten ein – =SUMME(Einkauf_1+Einkauf_2+Einkauf_n). Dann kann man letztendlich aber nicht mehr wirklich nachvollziehen, was die einzelnen Werte der Summe bedeuten. Ggf. wird sogar mal ein Wert vergessen.

Ich wollte eine bessere Lösung der Ausgabenerfassung. Deshalb erstelle ich ein separates Tabellenblatt Ausgaben und darin die intelligente Tabelle tab_Ausgaben. Hier trage ich dann alle Ausgaben ein, die chronologisch über das ganze Jahr verteilt anfallen. Dabei wird jede einzelne Ausgabe mit Datum, Ausgabenart und anfallende Kosten angegeben. Außerdem kann die Spalte Bemerkung genutzt werden, um Ausgaben rückwirkend besser nachvollziehen zu können (Konsumtagebuch).

Um die Kategorien für fixe und variable Ausgaben nicht immer wieder manuell eingeben zu müssen, nutze ich eine Auswahlliste. Diese kann im Menüpunkt Daten → Datenüberprüfung mit den entsprechenden Hilsftabellen erstellt werden. Als Gültigkeitskriterium wähle ich die Liste und unter Quelle wird der Verweis auf die entsprechende Hilfstabelle für die Ausgabenarten angegeben.

=INDIREKT("Hilfstabellen!hilfstab_Ausgaben_fix[Ausgabenart fix]")

=INDIREKT("Hilfstabellen!hilfstab_Ausgaben_variabel[Ausgabenart variabel]")

Hinweis: Hier kommt ein erstes Mal der Vorteil intelligenter Tabellen zum Vorschein. Mit der INDIREKT-Funktion kann ein textlicher Bezug auf die Spalte der entsprechenden Hilfstabelle gesetzt werden. Mit dieser Verknüpfung ist garantiert, dass das Popup-Menü, also die Auswahlliste garantiert alle Werte der Hilfstabellen anzeigt. Und eben nur so viele Werte, wie dort angegeben wurden. Außerdem wird die Auswahlliste automatisch aktualisiert, wenn in den Hilfstabellen eine Änderung vorgenommen wird.

Da die Tabelle tab_Ausgaben noch leer ist, formatiere ich nun die erste Eingabe-Zelle Datum zum Datumsformat und die Eingabe-Zelle Kosten zum Buchaltungszahlenformat. Diese Formatierung bezieht sich übrigens auch auf die weiteren Tabellen, die ich im Folgenden erstelle.

3. Einnahmen erfassen

Mit den Einnahmen handhabe ich es ähnlich wie mit den Ausgaben. Auch diese werden in einem separaten Tabellenblatt Einnahmen und der darin enthaltenen intelligenten Tabelle tab_Einnahmen chronologisch aufgelistet. So kann ich einerseits nachvollziehen, wann wie viel Geld eingegangen ist und andererseits automatisch (per Formel) mehrere derselben Einnahmenart in der Auswertung zusammenrechnen.

Auch hier nutze ich die Auswahlliste wie ich bei den Ausgaben schon beschrieben habe. Die Formel für die Quelle:

=INDIREKT("Hilfstabellen!hilfstab_Einnahmen[Einnahmenart]")

4. Zusatz – Sparplan erfassen

Bei den Sparraten gibt es unterschiedliche Meinungen, wenn es um die Erfassung im Haushaltsbuch geht. Ich habe mir lange Gedanken gemacht und bin letztendlich zu der Lösung gekommen, die Sparraten ebenfalls in einem separaten Tabellenblatt Sparen und hier in der Tabelle tab_Sparen aufzulisten.

Genaugenommen sind die Raten, mit denen z.B. ein Tagesgeldkonto gefüllt oder einen ETF-Sparplan bedient wird, ja keine Ausgaben. Jedoch werden sie in Form einer Ausgabe monatlich vom Girokonto abgebucht. Also doch eine Ausgabe? Jein…, jedenfalls nicht in meiner Excel-Haushaltsplan-Vorlage. Hier kann und sollte aber jede und jeder selbst entscheiden, wie sie oder er dies sehen möchte.

Für die Aufteilung der Sparraten achte ich auf die monatlichen Saldi – also, welcher Betrag am Ende eines jeden Monats übrigbleibt. Die Raten sollten insgesamt nicht höher, aber auch nicht wesentlich geringer als das jeweils verfügbare Saldo liegen.

Die Auswahl der Sparart erreiche ich auch hier wieder per Auswahlliste und mit der vorher erstellten Hilfstabelle. Die Formel für die Quelle ändert sich dann entsprechend zu:

=INDIREKT("Hilfstabellen!hilfstab_Sparen[Sparart]")

5. Die Auswertung des Haushaltsbuchs

Bei der Auswertung des Haushaltsbuchs stelle ich mir zuerst die Fragen, was ich überhaupt messen will und wie ich diese Ergebnisse inhaltlich und optisch gestalten möchte. So komme ich auf folgende Anforderung für das Tabellenblatt Übersicht – Zahlen:

• Monatliche kumulierte Auflistung und Auswertung nach Kategorien + Jahresbilanz
• Übersichtliche und visuell unterscheidbare Tabellen
  • Schnellübersicht – Gesamteinnahmen, Gesamtausgaben und Saldo
  • Einnahmen
  • Ausgaben (fix)
  • Ausgaben (variabel)
  • Sparplan

Außerdem erstelle ich noch ein weiteres Tabellenblatt Überblick – Diagramme:

• Grafische Auswertung in Form von Diagrammen
  • Schnellübersicht
  • Sparplan mit kumulierten Werten

Schnellübersicht – Gesamteinnahmen, Gesamtausgaben, Saldo

Die Tabelle mit der Schnellübersicht wird als erstes gelistet. Denn sie zeigt mir direkt, wie viel ich im jeweiligen Monat insgesamt eingenommen und ausgegeben habe. Außerdem sehe ich mit dem Saldo, also die Gesamteinnahmen minus die Gesamtausgaben, direkt, wie viel ich spare oder gar, ob ich über meine Verhältnisse lebe.

Hinweis: Damit die folgenden Formeln funktionieren, musst du dieses Kapitel erst einmal überspringen. Du kannst aber jetzt schonmal direkt die Tabelle tab_Schnelluebersicht mit ihrer Kopfzeile (Januar bis Dezember + letzte Spalte Jahr) sowie den drei Zeilen Gesamteinnahmen, Gesamtausgaben und Saldo erstellen (wie im folgenden Bild zu sehen). Nun springst du ein Kapitel weiter und erstellst die nachfolgenden vier Tabellen zur Auswertung deiner Daten. Anschließend kannst du die Schnellübersicht mit eben diesen Tabellen verknüpfen.

Die Gesamteinnahmen und -ausgaben werden nun mit den entsprechenden Ergebniszellen der jeweiligen Monate verknüpft. Diese Formeln kopierst du dann einfach über alle Monate hinweg bis zur letzten Spalte (Jahr) – ganz einfach durch Ziehen mit der Maus.

Gesamteinnahmen: alle aufsummierten Einnahmen eines Monats (hier für die Zelle Januar)

=tab_Einnahmen_ges[[#Ergebnisse];[Januar]]

Gesamtausgaben: alle aufsummierten fixe und variable Ausgaben eines Monats (hier für die Zelle Januar)

=tab_Ausgaben_fix[[#Ergebnisse];[Januar]]+tab_Ausgaben_variabel[[#Ergebnisse];[Januar]]

Achtung, die Zeile Saldo ist keine Ergebniszeile. Im Gegensatz zu den anderen Auswertungstabellen musst du hier also eine eigene Funktion eingeben. Dafür ist sie aber sehr einfach. Falls du doch mit Ergebniszeile und SUMME arbeiten möchtest, musst du die Gesamtausgaben in negative Zahlen umwandeln. Diesen Weg umgehe ich hier aber.

Saldo: Gesamteinnahmen minus Gesamtausgaben (im Folgenden ebenfalls für die Zelle Januar)

=B2-B3

Per bedingter Formatierung erstelle ich eine Regel, die das Saldo entsprechend automatisch formatieren soll. Werte > 0 sollen grün und Werte < 0 sollen rot markiert werden. Das persönliche Ziel sollte dann natürlich immer ein unterm Strich positiver, also ein grün formatierter Saldo sein.

Damit die Tabelle Schnellübersicht beim Scrollen immer sichtbar bleibt, fixiere ich sie – Ansicht → Fenster fixieren.

Auswertung – Einnahmen, Ausgaben und Sparplan

Die Tabellen zur Auswertung der Einnahmen (tab_Einnahmen_ges), Ausgaben (tab_Ausgaben_fix, tab_Ausgaben_variabel) und Sparraten (tab_Sparen_ges) sind im Prinzip immer gleich aufgebaut:

• Kopfzeile →: 1. Zelle beschreibt die Finanzart der jeweiligen Tabelle, die weiteren Zellen listen die Monate von Januar bis Dezember sowie das Jahr auf (musst du alles manuell eintragen)
• Tabellenspalten ↓: monatliche Auflistung der kompletten Einnahmen, Ausgaben und Sparraten
• Erste Spalte ↓ (ab 2. Zelle): automatisierte Auflistung der Kategorien der einzelnen Hilfstabellen (Einnahmenarten, Ausgabenarten – aufgeteilt in fixe und variable Ausgaben, Spararten)
• Tabellenzeilen → (ab 2. Zeile): einzelne kumulierte bzw. aufaddierte Werte der jeweiligen Kategorien
• Ergebniszeile →: die Summen der jeweiligen Monate – dies ist eine praktische Funktion der intelligenten Tabelle
• Letzte Spalte ↓: die Jahressummen der jeweiligen Kategorien, also die Summen der einzelnen Monate

Hinweis: Nutze die Checkboxen unter dem Menüpunkt Tabellen. Hier kannst du z. B. eine Ergebniszeile für die entsprechenden Tabellen einblenden. Dann musst du nur noch für die einzelnen Zellen in der Auswahlliste die SUMMEN-Funktion auswählen und erhältst das Ergebnis wie auf den Bildern zu sehen.

Wie so oft führen bekanntlich viele Wege nach Rom. Die folgenden Formeln müssen nicht zwangsläufig die effizienteste Art sein, aber sie sind effektiv und führen zum gewünschten Ziel. Bei deren Erstellung habe ich versucht, möglichst viel zu automatisieren. Außerdem habe ich überlegt, wo beim Führen des Haushaltsbuchs theoretisch Fehler gemacht und wie diese vermieden werden können.

Im Folgenden beziehe ich mich auf die Formeln für die Auswertungstabelle der Einnahmen. Die Formeln für die Ausgaben (fix und variabel) sowie für den Sparplan füge ich jeweils unten als Ergänzung an. Sie funktionieren auf dieselbe Art.

INDEX-Formel für die Auflistung der einzelnen Kategorien

Eine mögliche Fehlerquelle könnte z.B. sein, dass in der Auswertungstabellen einzelne Kategorien vergessen werden. Beispielsweise dann, wenn Kategorien in den Hilfstabellen geändert oder weitere hinzugefügt werden. Die entsprechende Tabelle für die Auflistung der Kategorien ist deshalb direkt mit den Hilfstabellen verknüpft.

=INDEX(INDIREKT("hilfstab_Einnahmen[Einnahmenart]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Einnahmen[Einnahmenart]"))/(INDIREKT("hilfstab_Einnahmen[Einnahmenart]")<>"");ZEILE()-ZEILE(tab_Einnahmen_ges[[#Kopfzeilen];[Einnahmen]]))-1;1)

Diese etwas komplexere Index-Formel geht im Prinzip Zeile für Zeile der Hilfstabelle hilfstab_Einnahmen durch und gibt bis zum letzten Eintrag alle Zellwerte aus, die nicht leer sind. Es werden also alle Kategorien nacheinander aufgelistet.

Nun muss ich nur noch darauf achten, dass die Auswertungstabelle mit ausreichend vielen Zeilen versehen ist. So viele, dass bis zur letzten Kategorie alle aufgelistet werden können. Füge ich also in der Hilfstabelle eine hinzu, so muss ich parallel auch eine weitere Zeile in der Auswertungstabelle hinzufügen. Dies birgt natürlich noch ein gewisses Fehlerpotenzial.

Ggf. gibt es hier also noch eine bessere Lösung. Um aber dennoch in der Auswertung garantiert keine Kategorie zu vergessen, hilft folgende Vorgehensweise:

• Eine Zeile mehr hinzufügen: Wird die Auswertungstabelle mit so vielen Zeilen aufgefüllt, bis die letzte leer bleibt, sind definitiv alle Kategorien aufgelistet worden.
• ANZAHL2 als Kontrollfunktion: Es gäbe die Möglichkeit, die Kategorien in der Hilfstabelle und gelisteten in der Auswertungstabelle per ANZAHL2 zu zählen. Per bedingter Formatierung könnte man dann beide Ergebnisse so formatieren, dass sie Rot angezeigt werden, wenn beide unterschiedlich sind und grün, wenn sie gleich sind.

Ergänzende INDEX-Formeln:

Hinweis: Aktuelle Excel-Versionen (Microsoft 365) verarbeiten die INDEX-Formel korrekt. Das heißt, du trägst die Formel ein und drückst die EINGABETASTE, um sie zu bestätigen. Anschließend wird der Formel automatisch ein @ vorangestellt. Bei älteren Excel-Versionen müssen die Formeln jedoch als Arrayformel bzw. Matrixformel eingegeben werden. Dies erreichst du durch die Tastenkombination STRG + UMSCHALT + EINGABETASTE. Hat alles geklappt, findest du jetzt eine geschweifte Klammer am Anfang und am Ende deiner Formel.

Ausgaben (fix)

=INDEX(INDIREKT("hilfstab_Ausgaben_fix[Ausgabenart fix]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Ausgaben_fix[Ausgabenart fix]"))/(INDIREKT("hilfstab_Ausgaben_fix[Ausgabenart fix]")<>"");ZEILE()-ZEILE(tab_Ausgaben_fix[[#Kopfzeilen];[Ausgaben (fix)]]))-1;1)

Ausgaben (variabel)

=INDEX(INDIREKT("hilfstab_Ausgaben_variabel[Ausgabenart variabel]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Ausgaben_variabel[Ausgabenart variabel]"))/(INDIREKT("hilfstab_Ausgaben_variabel[Ausgabenart variabel]")<>"");ZEILE()-ZEILE(tab_Ausgaben_variabel[[#Kopfzeilen];[Ausgaben (variabel)]]))-1;1)

Sparen

=INDEX(INDIREKT("hilfstab_Sparen[Sparart]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Sparen[Sparart]"))/(INDIREKT("hilfstab_Sparen[Sparart]")<>"");ZEILE()-ZEILE(tab_Sparen_ges[[#Kopfzeilen];[Sparen]]))-1;1)

SUMMENPRODUKT-Formel für das Aufsummieren der monatlichen Werte:

Um mehrere Werte derselben Kategorie im jeweiligen Monat zu addieren, habe ich mich für das SUMMENPRODUKT entschieden. Genauso wäre aber auch eine Formel mit SUMMEWENNS möglich.

=SUMMENPRODUKT((INDIREKT("tab_Einnahmen[Art]")=$A8)*(MONAT(INDIREKT("tab_Einnahmen[Datum]"))=MONAT("1."&tab_Einnahmen_ges[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Einnahmen[Wert]"))

Die ersten beiden Argumente prüfen eine Bedingung und das letzte Argument gibt an, welcher Wert bzw. welche Werte einer bestimmten Spalte zur Summenbildung verwendet werden soll.

• Argument 1: (INDIREKT(„tab_Einnahmen[Art]“)=$A8)
  Hier wird die Spalte Art der Tabelle tab_Einnahmen Zeile für Zeile durchsucht und mit der Kategorie verglichen, die links in der ersten Spalte steht. Die absolute Spalten- und relative Zeilenangabe $A8 muss natürlich entsprechend der tatsächlichen Position der Tabelle angepasst werden. Hier ist es eben die 8. Zeile.
• Argument 2: (MONAT(INDIREKT(„tab_Einnahmen[Datum]“))=MONAT(„1.“&tab_Einnahmen_ges[[#Kopfzeilen];[Januar]]))
  Hier wird die die Spalte Datum der Tabelle tab_Einnahmen Zeile für Zeile durchsucht und mit dem entsprechenden Monat in der Kopfzeile derselben Spalte verglichen – also mit Januar.
• Argument 3: INDIREKT(„tab_Einnahmen[Wert]“)
  Immer dann, wenn die ersten beiden Argumente übereinstimmen, wird der Wert zu einer Gesamtsumme addiert.

Treten also mehrere Einnahmen derselben Kategorie im selben Monat auf, werden sie insgesamt zu einer Gesamteinnahme aufsummiert.

Ergänzende SUMMENPRODUKT-Formeln:

Ausgaben (fix)

=SUMMENPRODUKT((INDIREKT("tab_Ausgaben[fix]")=$A46)*(MONAT(INDIREKT("tab_Ausgaben[Datum]"))=MONAT("1."&tab_Ausgaben_fix[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Ausgaben[Kosten]"))

Ausgaben (variabel)

=SUMMENPRODUKT((INDIREKT("tab_Ausgaben[variabel]")=$A77)*(MONAT(INDIREKT("tab_Ausgaben[Datum]"))=MONAT("1."&tab_Ausgaben_variabel[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Ausgaben[Kosten]"))

Sparen

=SUMMENPRODUKT((INDIREKT("tab_Sparen[Geldanlage]")=$A108)*(MONAT(INDIREKT("tab_Sparen[Datum]"))=MONAT("1."&tab_Ausgaben_variabel[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Sparen[Rate]")) 

Visualisierung – Diagramme

Zur besseren Veranschaulichung der Daten der Schnellübersicht eignet sich ein einfaches Säulendiagramm (gruppierte Säulen).

Das Diagramm zeigt von Januar bis Dezember jeweils drei Säulen an – die Gesamteinnahmen, Gesamtausgaben und den Saldo des Monats. Der optische Geschmack ist natürlich unterschiedlich. Ich für mich habe entschieden, die Einnahmen entsprechend grün und die Ausgaben orange mit Musterfüllung zu formatieren. Der Saldo wird hingegen in einer einfarbigen Füllung angezeigt und invertiert, wenn er negativ wird. Im positiven Bereich ist er also wie die Einnahmen grün und im negativen Bereich ist er orange.

Ein weiteres interessantes Diagramm ist die Darstellung der aufsummierten Raten des Sparplans. Dieses setze ich ebenfalls als gruppierte Säulen um. Wirtschafte ich nachhaltig mit meinem Haushalsbudget und investiere den Überschuss in sinnvolle Geldanlagen, kann ich anhand der Balken sehen, wie meine Sparsumme Monat für Monat anwächst. Dies sollte ein visueller Ansporn zum Sparen sein.

Außerdem kann ich durch die wachsenden Säulen sehen, wenn ein zuvor festgelegtes Sparziel erreicht ist. Ist das Konto mit dem Notgroschen gefüllt, habe ich die Möglichkeit, die Sparraten in andere Töpfe fließen zu lassen – z. B. in die Altersvorsorge mit ETFs und Aktien.

Um die Sparsummen in kumulierter Form im Diagramm wiedergeben zu können, benötige ich noch eine Hilfstabelle hilfstab_Sparen_kumuliert. Eigentlich gehört sie in das Tabellenblatt Hilfstabellen, ich positioniere sie aber direkt neben die Tabelle Sparen tab_Sparen_ges. Denn im Aussehen ist sie ein Abbild derer.

Um die Kategorien automatisch in die erste Spalte einzufügen, kann ich dieselbe INDEX-Formel verwenden, wie oben schon beschrieben. Die Zelleninhalte benötigen aber eine Formel, die die Gesamtsparsummen der Monate aufsummiert. Diese sieht folgendermaßen aus:

=WENN(tab_Sparen_ges[@Januar]>0;SUMME($B108:tab_Sparen_ges[@Januar]);"")

Es wird also nur aufsummiert, wenn schon ein Wert im jeweiligen Monat erfasst wurde. Ansonsten bleibt die Zelle leer.

6. Als Vorlage speichern

So viele Funktionen, Tabellen und Diagramme. Da ist es natürlich sinnvoll, wenn du schon von Beginn an regelmäßig gespeichert hast. Wenn jetzt alles funktioniert und du die Eingabe und Auswertung mit ein paar fiktiven Zahlen getestet hast, solltest du noch eines tun: Speichere das Dokument als Excel-Vorlage (.xltx).

Dadurch ist sichergestellt, dass du für jedes kommende Jahr immer auf dasselbe funktionierende Haushaltsbuch zurückgreifen kannst.

Fazit

Ich gebe es zu, ganz einfach ist es nicht, ein eigenes Excel-Haushaltsbuch zu erstellen. Außerdem ist es nicht von jetzt auf gleich getan. Du wirst dir Zeit nehmen müssen – schon alleine für die Aufstellung der einzelnen Kategorien. Aber der Aufwand ist es wert. Und bedenke: der beste Tag, mit der Dokumentation der eigenen Finanzen zu beginnen, ist der erste eines Monats. Also nutze die Tage bis dahin und kümmer dich um eines der wichtigsten Tools, das dich in den kommenden Monaten begleiten wird.

Du kannst dein Excel-Haushaltsbuch gerne eins zu eins wie oben beschrieben nachbauen. Das Tolle aber ist, du musst es nicht. Gestalte die Tabellen nach deinen Vorlieben. Excel bietet ja genügend Möglichkeiten an. Und wenn du die Eingaben lieber jeweils in ein separates Monats-Tabellenblatt unterteilen willst, dann los. Es gibt so viele Lösungswege, meiner ist nur einer davon und garantiert nicht in Stein gemeißelt. Vielleicht findest du für einige Funktionen einen besseren Weg (und bestimmt gibt es diesen auch).

Ich wünsche dir jedenfalls viel Spaß bei der Erstellung deiner eigenen Vorlage und freue mich, wenn ich dazu beitragen konnte, deine Excel-Kenntnisse zu erweitern.